Solve Day 4, Task 2

day_4/Makefile

@@ -0,0 +1,54 @@
+CC := clang
+YACC := bison
+LEX := flex
+CFLAGS := -std=c17 -Wpedantic -Wall -Wextra
+BUILD := ./build
+INCLUDE	:= -I./
+OBJ_DIR := $(BUILD)/objects
+APP_DIR := $(BUILD)/bin
+TARGET := day_4
+
+SRC := $(wildcard ./*.cpp) lexer.c parser.c
+
+OBJECTS	:= $(SRC:%.c=$(OBJ_DIR)/%.o)
+
+# targets
+all: build $(APP_DIR)/$(TARGET)
+
+run: all
+	$(APP_DIR)/$(TARGET)
+
+flex:
+	$(LEX) --outfile=lexer.c --header-file=lexer.h lexer.l
+
+bison:
+	$(YACC) --output=parser.c parser.y
+
+generate: flex bison
+
+$(OBJ_DIR)/%.o: %.c
+	@mkdir -p $(@D)
+	$(CC) $(CFLAGS) $(INCLUDE) -o $@ -c $<
+
+$(APP_DIR)/$(TARGET): flex bison $(OBJECTS)
+	@mkdir -p $(@D)
+	$(CC) $(CFLAGS) $(INCLUDE) $(LDFLAGS) -o $(APP_DIR)/$(TARGET) $(OBJECTS)
+
+.PHONY: all build clean debug release
+
+build:
+	@mkdir -p $(APP_DIR)
+	@mkdir -p $(OBJ_DIR)
+
+debug: CFLAGS += -DDEBUG -g
+debug: all
+
+sanitize: CFLAGS += -DDEBUG -g -fsanitize=address
+sanitize: all
+
+release: CFLAGS += -O2
+release: all
+
+clean:
+	-@rm -rvf $(BUILD)
+	-@rm -rvf {lexer.c,parser.c} {lexer.h,parser.h}

day_4/lexer.l

@@ -0,0 +1,50 @@
+%{ /* -*- C -*- */
+#include <stdio.h>
+#include <stdlib.h>
+#include "parser.h"
+%}
+
+%option warn nodefault
+
+/* makes the scanner terminate after reaching <<EOF>> instead of assuming a new input was provided */
+%option noyywrap
+/* disable some unused functionality, add scanner tracking */
+%option nounput noinput batch debug
+
+/* gimme a reentrant parser (overkill but more pure) */
+%option reentrant
+
+%option bison-bridge
+
+
+NL      [\n]
+NUM     [0-9]
+MINUS   [-]
+COMMA   [,]
+
+
+%%
+
+{NL}        {
+                return NEWLINE;
+            }
+{NUM}+      {
+                unsigned long num = strtoul(yytext, NULL, 10);
+                yylval->num = num;
+                return NUMBER;
+            }
+{MINUS}     {
+                return MINUS;
+            }
+{COMMA}     {
+                return SEP;
+            }
+<<EOF>>     {
+                return END_OF_FILE;
+            }
+.           {
+                printf("[error] Encountered unexpected token %s\n", yytext);
+                return 0;
+            }
+
+%%

day_4/parser.y

@@ -0,0 +1,113 @@
+/* Require bison minimal version */
+%require "3.2"
+
+/* write out a header file containing the token defines */
+%header
+
+// Code for the header file generated by bison
+%code requires {
+    typedef void* yyscan_t;
+
+    struct parser_state {
+        unsigned long num_fully_contained;
+        unsigned long num_partial_overlaps;
+    };
+}
+
+// Code for the c file
+%{
+    #include <stdio.h>
+    #include <stdlib.h>
+    #include "parser.h"
+    #include "lexer.h"
+
+    void yyerror(struct parser_state* state, yyscan_t scanner, const char* msg) {
+        (void)state;
+        (void)scanner;
+        fprintf(stderr, "\033[93mSyntax Error: %s\033[0m\n", msg);
+    }
+%}
+
+// define a reentrant parser
+%define api.pure
+
+// enable parser tracing and detailed error messages (plus Lookahead Correction)
+%define parse.trace
+%define parse.error detailed
+%define parse.lac full
+
+%lex-param   { yyscan_t scanner }
+%parse-param { struct parser_state* state }
+%parse-param { yyscan_t scanner }
+
+%union {
+    unsigned long num;
+}
+
+
+%start input
+%token NEWLINE MINUS SEP
+%token <num> NUMBER
+%term END_OF_FILE
+
+%%
+
+input
+    : line input
+    | END_OF_FILE       { return 0; }
+    ;
+
+line
+    : section_list NEWLINE
+    | NEWLINE
+    ;
+
+section_list
+    : NUMBER MINUS NUMBER SEP NUMBER MINUS NUMBER   {
+        if ($1 <= $5) {
+            if ($3 >= $7) {
+                // pair 1 contains pair 2 fully
+                state->num_fully_contained++;
+            }
+            if ($3 >= $5) {
+                state->num_partial_overlaps++;
+            }
+        } else if ($5 <= $1) {
+            if ($7 >= $3) {
+                // pair 2 contains pair 1 fully
+                state->num_fully_contained++;
+            }
+            if ($7 >= $1) {
+                state->num_partial_overlaps++;
+            }
+        }
+    }
+    ;
+
+%%
+
+int main(void) {
+    struct parser_state parser_state;
+    parser_state.num_fully_contained = 0;
+    parser_state.num_partial_overlaps = 0;
+    
+    yyscan_t scanner;
+
+    if (yylex_init(&scanner)) {
+        fprintf(stderr, "\033[91m[error] Could not initialize lexer\n");
+        return EXIT_FAILURE;
+    }
+
+    if (yyparse(&parser_state, scanner)) {
+		// TODO: Error handling https://www.gnu.org/software/bison/manual/html_node/Parser-Function.html
+		// error during parse occured
+		return EXIT_FAILURE;
+	}
+
+    yylex_destroy(scanner);
+    
+    printf("Number of fully contained pairs: %lu\n", parser_state.num_fully_contained);
+    printf("Number of partial overlaps: %lu\n", parser_state.num_partial_overlaps);
+
+    return 0;
+}